---

Hey..
Er der nogen der kan se fejlen her, for jeg er ved at være
skaldet, den siger at der er forventet et " i strSQL
sætningen...........

For each Item in Request.Form
   If Item = "fnavn" Then
      fnavn = Request.Form(Item)
   ElseIf Item = "enavn" Then
      enavn = Request.Form(Item)
   ElseIf Item = "adr" Then
      adr = Request.Form(Item)
   ElseIf Item = "farve" Then
      farve = Request.Form(Item)
   ElseIf Item = "avis" Then
      avis = Request.Form(Item)
   ElseIf Item = "boeger" Then
      For i = 1 To Request.Form(Item).Count
      Redim Preserve arrBog(i)
         arrBog(i) = Request.Form(Item)(i)
      Next
   ElseIf Item = "tv" Then
      For i = 1 To Request.Form(Item).Count
      Redim Preserve arrTV(i)
         arrTV(i) = Request.Form(Item)(i)
      Next
   End If
Next

Dim strConn, objConn, objRS, strSQL

Set objConn = Server.CreateObject("ADODB.Connection")
objConn.Open "DSN=Guest2000"

Set objRS = Server.CreateObject("ADODB.recordset")
objRS.Open "guest", objConn

strSQL = "INSERT INTO guest(fnavn, enavn, adr, farve, avis)
VALUES (fnavn, enavn, adr, farve, avis)"


strConn.CommandText = strSQL
strConn.CommandType = adCmdText
strConn.Execute

--
Vil du lære at kode HTML, XHTML, CSS, SSI eller ASP ???
- Pædagogiske tutorials på dansk
- Kom godt i gang med koderne
KLIK HER! => http://www.html.dk/tutorials

---

Nicolai wrote:
>
> Er der nogen der kan se fejlen her
Jeg kan se flere.

> for jeg er ved at være skaldet, den siger at der er
> forventet et " i strSQL sætningen.
>
> For each Item in Request.Form
> If Item = "fnavn" Then
> fnavn = Request.Form(Item)
> ElseIf Item = "enavn" Then
> enavn = Request.Form(Item)
> ElseIf Item = "adr" Then
> adr = Request.Form(Item)
> ElseIf Item = "farve" Then
> farve = Request.Form(Item)
> ElseIf Item = "avis" Then
> avis = Request.Form(Item)
> ElseIf Item = "boeger" Then
> For i = 1 To Request.Form(Item).Count
> Redim Preserve arrBog(i)
> arrBog(i) = Request.Form(Item)(i)
> Next
> ElseIf Item = "tv" Then
> For i = 1 To Request.Form(Item).Count
> Redim Preserve arrTV(i)
> arrTV(i) = Request.Form(Item)(i)
> Next
> End If
> Next

Hvorfor ikke blot:

fnavn = Request.Form("fnavn")
enavn = Request.Form("enavn")
adr = Request.Form("adr")
farve = Request.Form("farve")
avis = Request.Form("avis")
Redim arrBog(Request.Form("boeger").Count)
For i = 1 To Request.Form("boeger").Count
arrBog(i) = Request.Form("boeger")(i)
Next
Redim arrTV(Request.Form("tv").Count)
For i = 1 To Request.Form("tv").Count
arrTV(i) = Request.Form("tv")(i)
Next

> Dim strConn, objConn, objRS, strSQL
>
> Set objConn = Server.CreateObject("ADODB.Connection")
> objConn.Open "DSN=Guest2000"
>
> Set objRS = Server.CreateObject("ADODB.recordset")
> objRS.Open "guest", objConn

Du benytter ikke recordsettet og hvorfor åbner du det?

> strSQL = "INSERT INTO guest(fnavn, enavn, adr, farve, avis)
> VALUES (fnavn, enavn, adr, farve, avis)"

Du mener
strSQL = "INSERT INTO guest(fnavn, enavn, adr, farve, avis) " & _
"VALUES (" & _
StrToSql(fnavn) & " ," & _
StrToSql(enavn) & " ," & _
StrToSql(adr) & " ," & _
StrToSql(farve) & " ," & _
StrToSql(avis) & " )"

Function StrToSql(ByVal v)
If Trim("" & v) = "" Then
StrToSql = "NULL"
Else
StrToSql = "'" & Replace(v, "'", "''") & "'"
End If
End Function

> strConn.CommandText = strSQL
> strConn.CommandType = adCmdText
> strConn.Execute

Eller blot:
Conn.Execute strSQL

--
Anders