Lars Klingenberg wrote:
>
> Dokumentet er en vejledning som indeholder en del forskellige
> afsnit (angivet med <h1>) og tilhørende underafsnit i
> forskellige niveauer (angivet med <h2>, <h3>,...). Øverst på
> siden vil jeg gerne have en TOC, som gerne skulle genereres
> automatisk, når jeg indsætter et afsnit/underafsnit. Det ville
> være helt perfekt, hvis man kunne lave TOC som links også,
<%
Option Explicit
Dim fso, f, Content
Set fso = Server.CreateObject("Scripting.FileSystemObject")
Set f = fso.OpenTextFile(Server.MapPath("outline.htm"), 1, False)
Content = f.ReadAll
f.Close
Response.Write CreateToc(Content)
Function CreateToc(ByVal Content)
Dim regEx, Match, Matches, Toc, Offset, Count, Pos, Anchor
Dim OldTocLevel, TocLevel
Offset = 0
Count = 0
TocLevel = -1
Set regEx = New RegExp
regEx.Pattern = "<h([1-6])>(.*?)</h\1>"
regEx.IgnoreCase = True
regEx.Global = True
Set Matches = regEx.Execute(Content)
For Each Match in Matches
Count = Count + 1
Pos = Match.FirstIndex + Offset
Anchor = "<a name=""h" & Count & """></a>"
Offset = Offset + Len(Anchor)
Content = Left(Content, Pos) & Anchor & _
Mid(Content, Pos + 1)
TocLevel = CLng(Match.SubMatches(0))
Do While (TocLevel > OldTocLevel)
Toc = Toc & "<ul>" & vbCrLf
OldTocLevel = OldTocLevel + 1
Loop
Do While (TocLevel < OldTocLevel)
Toc = Toc & "</ul>" & vbCrLf
OldTocLevel = OldTocLevel - 1
Loop
Toc = Toc & "<li><a href=""#h" & Count & """>" & _
Match.SubMatches(1) & "</a>" & vbCrLf
Next
Do While (0 < OldTocLevel)
Toc = Toc & "</ul>" & vbCrLf
OldTocLevel = OldTocLevel - 1
Loop
CreateToc = Toc & Content
End Function
%>