---

Her er en function som kan sende mail med attachments og priotet.

<%
function SendMail(sTo, sFrom, sPriority, sSubject, sBody, sAttachment, bHTML)
on error resume next
cdoLow = 0 ' Lav priotet
cdoNormal = 1 ' Normal priotet (default)
cdoHigh = 2 ' Høj priotet

cdoBodyFormatHTML = 0
cdoBodyFormatText = 1
cdoMailFormatMime = 0
cdoMailFormatText = 1


'Opret CDONTS komponent.
Set oMailMessage = server.CreateObject("CDONTS.NewMail")
oMailMessage.To = sTo
' Reply to
oMailMessage.Value("Reply-To") = sFrom
oMailMessage.From = sFrom
oMailMessage.subject = sSubject

sPriority = ucase(sPriority)
if sPriority = "LOW" then
oMailMessage.importance = cdoLow
elseif sPriority = "HIGH" then
oMailMessage.importance = cdoHigh
else
oMailMessage.importance = cdoNormal
end if


' Skal beskeden være HTML besked
if bHTML then
oMailMessage.BodyFormat = cdoBodyFormatHTML
oMailMessage.MailFormat = cdoMailFormatMime
else
oMailMessage.BodyFormat = cdoBodyFormatText
oMailMessage.MailFormat = cdoMailFormatText
end if

oMailMessage.Body = sBody

if sAttachment <> "" then
oMailMessage.Attachfile sAttachment
end if

' Send besked.
oMailMessage.Send


set oMailMessage = nothing

if Err then
SendMail = false
else
SendMail = true
end if

end function
%>

---

---

---

---

---

Eftersom du ikke er logget ind i systemet, kan du ikke lave en bedømmelse til dette tip.

Hvis du ikke allerede er registreret, kan du gratis blive medlem, ved at trykke på "Bliv medlem" ude i menuen.